OpenSCADとUltimaker Curaを使用して、タミヤのユニバーサルプレート用のサーボモーター固定部品を作る

OpenSCADとUltimaker Curaを使用して、タミヤのユニバーサルプレート用のサーボモーター固定部品を作るには以下の手順を実行します。
サイズはサーボモーターSG90-HVに合わせてあります。

〇作成したサーボモーター固定部品の写真

作成手順

1. OpenSCADで以下のコードを実行して形状を調整し、STLファイルにエクスポートします。
穴の半径など3Dプリンタや設定によってパラメータを微調整してください。

・タミヤのユニバーサルプレートにつける事のできるサーボモーター固定部品のOpenSCADコード

// servo mounter
MOUNTER_THICK=2;

MOUNTER_W=23;
MOUNTER_D=9;
HOLE_RADIUS=1;

HANDLE_W = 5;
HANDLE_H=12.2;

SHAFT_DIAMETER=3+0.1;
SHAFT_DISTANCE=5;
SHAFT_HEIGHT=3;
NUM_SHAFT_W=6;
NUM_SHAFT_D=2;
D_OFFSET=0.5;
W_OFFSET=1.25;
W_MARGIN=1.3;


module tamiya_servo_mounter()
{
    difference()
    {
        union()
        {
            translate([-HANDLE_W, 0, 0])
            linear_extrude(height=MOUNTER_THICK){
                square([MOUNTER_W+HANDLE_W*2, MOUNTER_D]);
            }

            translate([-HANDLE_W, 0, MOUNTER_THICK])
            linear_extrude(height=HANDLE_H){
                square([HANDLE_W, MOUNTER_D]);
            }
            translate([MOUNTER_W, 0, MOUNTER_THICK])
            linear_extrude(height=HANDLE_H){
                square([HANDLE_W, MOUNTER_D]);
            }
        }
        rotate([-90,0,0])
        translate([-HANDLE_W/2, -MOUNTER_THICK-HANDLE_H/2, 0])
        linear_extrude(height=MOUNTER_D){
            circle(HOLE_RADIUS, $fn=50);
        }
        rotate([-90,0,0])
        translate([MOUNTER_W+HANDLE_W/2, -MOUNTER_THICK-HANDLE_H/2, 0])
        linear_extrude(height=MOUNTER_D){
            circle(HOLE_RADIUS, $fn=50);
        }

    }   


    for( lw = [0 : NUM_SHAFT_W-1] ){
        for( ld = [0 : NUM_SHAFT_D-1] ){
            translate([SHAFT_DISTANCE*lw+SHAFT_DIAMETER/2+W_OFFSET-SHAFT_DISTANCE+W_MARGIN, SHAFT_DISTANCE*ld+SHAFT_DIAMETER/2+D_OFFSET, -SHAFT_HEIGHT])
            linear_extrude(height=SHAFT_HEIGHT){
                circle(SHAFT_DIAMETER/2, $fn=50);
            }
        }
    }


}
rotate([180,0,0])
tamiya_servo_mounter();

・OpenSCADの画面

2. Ultimaker CuraでSTLファイルを読み込み、スライスしてgcodeを保存します。

3. 3Dプリンターで印刷します

追加情報

下図のように固定位置を高くしたい場合は、MOUNER_THICKパラメータの値を大きくしてください(下図ではMOUNTER_THICK=2+10;に設定しています)。

関連情報

・Raspberry Pi Picoと赤外線受信モジュールとサーボモーターで赤外線リモコンカーを作成する

・OpenSCADとUltimaker Curaを使用して、タミヤのユニバーサルプレートにRaspberry Pi Picoを固定する事のできるマウンタを作成する

・OpenSCADとUltimaker Curaを使用して、サーボモーターにつける事ができるホイールを作成する

・そのほかの3Dプリンターを活用した記事は以下を参照してください。
OpenSCADまとめ