OpenSCADとUltimaker Curaを使用して、LEGO互換の突起がついたサーボモーター固定台を作る

OpenSCADとUltimaker Curaを使用して、LEGO互換の突起がついたサーボモーター固定台を作るには以下の手順を実行します。

〇LEGO互換の突起がついたサーボモーター固定台の写真

※白色のサーボモーター固定台が今回作った物、黒色のプレートは純正のLEGOブロックです。

作成手順

1. OpenSCADで以下のコードを実行して形状を調整し、STLファイルにエクスポートします。
穴の半径など3Dプリンタや設定によって微調整してください。

・LEGO互換の突起がついたサーボモーター固定台の突起部分

// プレートの厚さ
PLATE_THICK=1;

// LEGOの1ブロック
LEGO_SQUARE=7.95;
// 突起の直径
LEGO_PEG=4.8;
LEGO_PEG_R=LEGO_PEG/2;
LEGO_PEG_H=1.8;

// プレートのサイズ(ブロック単位)
NUM_HOLE_W=4;
NUM_HOLE_D=3;

translate([0, 0, 0])
linear_extrude(height=PLATE_THICK){
    square([LEGO_SQUARE*NUM_HOLE_W, LEGO_SQUARE*NUM_HOLE_D]);
}

for( lw = [0 : NUM_HOLE_W-1] ){
    for( ld = [0 : NUM_HOLE_D-1] ){
        translate([LEGO_SQUARE*lw+LEGO_SQUARE/2, LEGO_SQUARE*ld+LEGO_SQUARE/2, PLATE_THICK])
        linear_extrude(height=LEGO_PEG_H){
            circle(LEGO_PEG_R, $fn=50);
        }
    }
}

・OpenSCADの画面(突起部分)

・LEGO互換の突起がついたサーボモーター固定台の固定台部分

// LEGO servo mounter
// 底版の厚さ
MOUNTER_THICK=1;
// サーボ固定アームオフセット
ARM_OFFSET=6.4;
// サーボ固定アーム間距離
ARM_DISTANCE=22.5;

// LEGOの1ブロック
LEGO_SQUARE=7.95;
// プレートのサイズ(ブロック単位)
NUM_HOLE_W=4;
NUM_HOLE_D=3;

// サーボ固定アーム
MOUNTER_HANDLE_D=8;
MOUNTER_HANDLE_H=12.2;
MOUNTER_HANDLE_W=4.65;

// ネジ穴
HOLE_RADIUS=0.9;

module lego_servo_base()
{
    difference()
    {
        union()
        {
            translate([0, 0, 0])
            linear_extrude(height=MOUNTER_THICK){
                square([LEGO_SQUARE*NUM_HOLE_W, LEGO_SQUARE*NUM_HOLE_D]);
            }

            translate([0, ARM_OFFSET, MOUNTER_THICK])
            linear_extrude(height=MOUNTER_HANDLE_H){
                square([MOUNTER_HANDLE_W, MOUNTER_HANDLE_D]);
            }
            translate([ARM_DISTANCE+MOUNTER_HANDLE_W, ARM_OFFSET, MOUNTER_THICK])
            linear_extrude(height=MOUNTER_HANDLE_H){
                square([MOUNTER_HANDLE_W, MOUNTER_HANDLE_D]);
            }
        }

        rotate([-90,0,0])
        translate([MOUNTER_HANDLE_W/2, -MOUNTER_THICK-MOUNTER_HANDLE_H/2, ARM_OFFSET])
        linear_extrude(height=MOUNTER_HANDLE_D){
            circle(HOLE_RADIUS, $fn=50);
        }
        rotate([-90,0,0])
        translate([MOUNTER_HANDLE_W/2+ARM_DISTANCE+MOUNTER_HANDLE_W, -MOUNTER_THICK-MOUNTER_HANDLE_H/2, ARM_OFFSET])
        linear_extrude(height=MOUNTER_HANDLE_D){
            circle(HOLE_RADIUS, $fn=50);
        }

    }   
}
lego_servo_base();

・OpenSCADの画面(固定台部分)

2. Ultimaker CuraでSTLファイルを読み込み、スライスしてgcodeを保存します。

3. 3Dプリンターで印刷します
固定部分と突起部分の２つのパーツを印刷します。

4. タミヤセメントなどの接着剤で突起部分とサーボ固定台部分を接着します。クリップなどで固定するとより強固に接着できます。

関連情報

・OpenSCADまとめ

・OpenSCADとUltimaker Curaを使用して、LEGO互換の凹みがついたサーボモーター固定台を作る
LEGOプレートの上にサーボモーターを配置したい場合は以下のページを参照してください。

・OpenSCADとUltimaker Curaを使用して、LEGO Technic互換の穴とSG90ギアに対応する穴がついた十字アームを作る